Nixie Röhren

Ich finde Nixie Röhren haben einen ganz speziellen Charakter. Die sehen einfach cool aus 🙂
Leider ist mir nichts besseres eingefallen, als auch eine Uhr aus den Röhren zu bauen – wie viele andere es schon gemacht haben. Aber was solls, dann haben wir halt ne Uhr mehr 😉

Nixie-Röhren ist eine alte Technik für Anzeigen. Die gibt es nicht nur mit Ziffern. Das coole an Nixie-Röhren ist, dass diese pro Ziffer eine Art Glimmdraht haben. Legt man an den Draht eine Spannung fängt die Ziffer an zu glimmen/leuchten.

2014-03-23 19.35.29

Zum Betrieb der Röhren braucht man eine Spannung um 170 V – da war ich etwas faul und habe mir direkt ein passende Schaltung mitbestellt, die aus 12 V regelbar bis zu 200 V macht.

Jetzt muss ich mir nur noch ein schickes Gehäuse überlegen, eine Schaltung aufbauen, alles verlöten und einbauen, dann noch den Quelltext schreiben, …. 😀

IV-18 Tube

Ich wollte schon immer mal eine Nixie Uhr bauen. Der ebay-Händler bei dem ich mir die Nixies besorgt habe, hatte auch sehr günstig ein Doppelpack IV-18 Röhren im Angebot. Also muss ich halt 2-3 Uhren bauen 😀

Die IV-18 Röhre wird waagerecht eingebaut und zeigt acht 7-Segment-Anzeigen + Vorzeichen. Grundsätzlich hat die IV-18 nichts mit den glühenden Nixie-Röhren zu tun, da die Nixies Glühdrähte haben und die IV-18 eine Fluoreszenzanzeige ist.

Ich habe mich an der Ice-Tube-Clock von Adafruit orientiert. Aus dem Schaltplan habe ich mir die Spannungsversorgung rausgesucht. Den Microcontroller-Teil habe ich dann aber angepasst. Ich will keine Taster zum Einstellen der Uhrzeit sondern einen DCF77 Empfänger, der das für mich macht. Die Software für die Uhr will ich auch selbst schreiben. Zudem stellt Adafruit den Microcontroller auf eine andere Frequenz ein und lässt diesen die Uhrzeit weiter zählen. Aus meiner Erfahrung ist das eher ungenau und ich finde es auch unnötig kompliziert. In meiner Schaltung habe ich für die Aufgabe eine RTC verbaut.

Die Röhre braucht eine relativ hohe Spannung für den Betrieb (~60 V). Als Eingangsspannung für die ganze Schaltung sind aber nur 12 V verfügbar. Das Boost Power Supply von LadyAda sorgt mit Hilfe von Induktion für eine Erhöhung der Spannung. Dazu wird eine Spule (der Induktor) mit einer gewissen Frequenz geladen und entladen. Durch die Induktion wird eine hohe Spannung erzeugt. Diese wird durch Kondensatoren geglättet, sodass man eine halbwegs konstante Spannung erreicht, die höher ist als die Eingangsspannung.
Die Frequenz bestimmt die Ausgangsspannung. Zum Erzeugen der Frequenz wird ein PWM-Ausgang am Microcontroller benutzt. So kann man über den Quelltext die Spannung regeln.
Mit der originalen PWM-Frequenz des Arduino habe ich leider eine Resonanzfrequenz des Induktors getroffen – die Spule fing an zu singen. Wie man die PWM-Frequenz ändern kann steht hier.

Das Ansteuern der Anzeige erfolgt über ein Multiplexen der einzelnen 7-Segment-Anzeigen. Über den MAX6921 Treiber werden pro Spalte die gewünschten Segmente eingeschaltet. Beim Multiplexen leuchtet immer nur eine Anzeige zur gleichen Zeit. Das Auge ist aber träge und bekommt den schnellen Wechsel der Spalten nicht mit – dadurch sieht es so aus als würden alle gleichzeitig leuchten.

Aktuell habe ich die RTC angebunden und das Multiplexen programmiert. Was noch fehlt ist eine zuverlässige Anbindung des DCF77-Empfängers und ein Gehäuse. Die aktuelle DCF77-Implementierung will noch nicht so richtig. Quelltext siehe unten.

 

 

Quelltext

#include "DS1307RTC.h"
#include "Wire.h"
#include "DCF77.h"
#include "Time.h"
 
//////////////
// Settings //
//////////////

// Pin-Settings
#define VFDPWR    9 // Power On/Off the VCC for the Tube and the Driver
#define BLANK     7 // Driver: If this is HIGH, the driver sets all Outputs to LOW
#define LOAD      8 // Driver: Loads the data from shift register to output latch
#define CLK      13 // Driver: Shifts in a Bit on rising edge
#define DIN      11 // Driver: Data In (gets shiftet on CLK rising edge)
#define BOOST    10 // PWM-Signal for boost power supply
#define DCF_DATA  2 // DCF: Data Pin
#define DCF_INT   0 // DCF: Interrupt of DCF_DATA Pin

//////////////
// Mappings //
//////////////

// Decimal numbers to bitmask for the 7-segments (+ decimal Point)
uint8_t number_bitmask[11] = {
  0b11101110, // 0
  0b00100100, // 1
  0b01111010, // 2
  0b01110110, // 3
  0b10110100, // 4
  0b11010110, // 5
  0b11011111, // 6
  0b01100100, // 7
  0b11111110, // 8
  0b11110111, // 9
  0b00000000  // 10 = off
};

// Bitmask for selecting the digits from left to right
uint8_t digit_bitmask[9] = {
  0b00000100, // left most 7-segment digit
  0b00100000,
  0b00010000,
  0b00001000,
  0b01000000,
  0b00000010,
  0b10000000,
  0b00000001, // right most 7-segment digit
  0b00000000  // signs (dot and minus)
};

// Bitmasks for the minus and the dot
uint8_t dot_bitmask   = 0b00000001;
uint8_t minus_bitmask = 0b00010000;

/////////////////
// Global vars //
/////////////////
boolean dot = true;
boolean minus = false;

byte current_digit = 0;
byte display_value[8] = {0,0,10,0,0,10,0,0};

DCF77 DCF = DCF77(DCF_DATA,DCF_INT);

////////////////////////////////////////////////////////////////////////////////

///////////
// Setup //
///////////
void setup(){
  pinMode(VFDPWR,  OUTPUT);
  pinMode(BLANK,   OUTPUT);
  pinMode(LOAD,    OUTPUT);
  pinMode(CLK,     OUTPUT);
  pinMode(DIN,     OUTPUT);
  
  digitalWrite(VFDPWR, LOW); // Enable VFD-Module
  digitalWrite(BLANK , LOW); // Disable blank
  
  DCF.Start();
  RTC.set(0);
  
  // Divide PWM frequency to prevent inductor from singing
  setPwmFrequency(BOOST, 8);
  analogWrite(BOOST,40);
}

//////////
// Loop //
//////////
void loop(){
  // Set Boost-Value with Poti and display on Tube
//  byte val = map(analogRead(A1),0,1023,0,255);
//  analogWrite(BOOST,val);
  /*
  display_value[7] = val % 10;
  display_value[6] = (val/10) % 10;
  display_value[5] = val/100;
  */
  
  time_t DCFtime = DCF.getTime(); // Check if new DCF77 time is available
  if(DCFtime != 0){
    RTC.set(DCFtime);
    dot = false;
  }
   
  time_t rtc_time = RTC.get();
  display_value[0] = hour(rtc_time)/10;
  display_value[1] = hour(rtc_time)%10;
  display_value[3] = minute(rtc_time)/10;
  display_value[4] = minute(rtc_time)%10;
  display_value[6] = second(rtc_time)/10;
  display_value[7] = second(rtc_time)%10;
  
  // Show Value on Tube
  multiplex();
}

////////////////////////////////////////////////////////////////////////////////

////////////////////////////
// display values on tube //
////////////////////////////
void multiplex(){
  uint8_t value = 0;
  boolean signs = LOW;
  
  if(current_digit == 9) current_digit = 0;
  
  if(current_digit == 8){
    if(dot) value = value | dot_bitmask;
    if(minus) value = value | minus_bitmask;
    signs = HIGH;
  }else{
    value = number_bitmask[display_value[current_digit]];
  }
  
  digitalWrite(LOAD, LOW);
  
  my_shiftOut(DIN, CLK, digit_bitmask[current_digit]);

  digitalWrite(DIN, signs);
  digitalWrite(CLK, LOW);
  digitalWrite(CLK, HIGH);
  
  digitalWrite(DIN, LOW);
  digitalWrite(CLK, LOW);
  digitalWrite(CLK, HIGH);
  
  digitalWrite(DIN, LOW);
  digitalWrite(CLK, LOW);
  digitalWrite(CLK, HIGH);
  
  digitalWrite(DIN, LOW);
  digitalWrite(CLK, LOW);
  digitalWrite(CLK, HIGH);
  
  my_shiftOut(DIN, CLK, value);

  digitalWrite(LOAD, HIGH);
  
  current_digit++;
}

//////////////
// Changed original shiftOut to use rising edge instead of falling edge
//////////////
void my_shiftOut(uint8_t dataPin, uint8_t clockPin, uint8_t val){
  uint8_t i;

  for(i = 0; i < 8; i++){
    digitalWrite(dataPin, !!(val & (1 << (7 - i))));
    digitalWrite(clockPin, LOW);
    digitalWrite(clockPin, HIGH);
  }
}

//////////////
// Divide PWM Frequency
//////////////
// http://playground.arduino.cc/Code/PwmFrequency#.UySCqdt1uVc
void setPwmFrequency(int pin, int divisor) {
  byte mode;
  if(pin == 5 || pin == 6 || pin == 9 || pin == 10) {
    switch(divisor) {
      case 1: mode = 0x01; break;
      case 8: mode = 0x02; break;
      case 64: mode = 0x03; break;
      case 256: mode = 0x04; break;
      case 1024: mode = 0x05; break;
      default: return;
    }
    if(pin == 5 || pin == 6) {
      TCCR0B = TCCR0B & 0b11111000 | mode;
    } else {
      TCCR1B = TCCR1B & 0b11111000 | mode;
    }
  } else if(pin == 3 || pin == 11) {
    switch(divisor) {
      case 1: mode = 0x01; break;
      case 8: mode = 0x02; break;
      case 32: mode = 0x03; break;
      case 64: mode = 0x04; break;
      case 128: mode = 0x05; break;
      case 256: mode = 0x06; break;
      case 1024: mode = 0x7; break;
      default: return;
    }
    TCCR2B = TCCR2B & 0b11111000 | mode;
  }
}